git.8kb.co.uk Git - postgresql/pgbench_looper/blob - pgbench_looper.p

   1 # Gnuplot script file for plotting pgbench data in csv file pgbench_looper.sh
   2 # Filename: pgbench_looper.p
   3 # Usage: gnuplot -e "filename='test-20130407_16-26.csv'" pgbench_looper.p -persist
   4 #        gnuplot -e "filename='test-20130407_16-26.csv' outfilename='test-20130407_16-26.png'" pgbench_looper.p
   5
   6 if (!exists("filename")) filename='pgbench_looper.csv'
   7 if (exists("outfilename")) set terminal png truecolor giant; set output outfilename
   8 set datafile separator ","
   9 set logscale y
  10 set mxtics 10
  11 set mytics 10
  12 set grid xtics mxtics ytics mytics
  13 set style line 11 lc rgb '#808080' lt 1
  14 set border 3 back ls 11
  15 set tics nomirror
  16 set style line 12 lc rgb '#808080' lt 0 lw 1
  17 set grid back ls 12
  18 set style line 1 lc rgb '#8b1a0e' pt 1 ps 1 lt 1 lw 2 # --- red
  19 set style line 2 lc rgb '#5e9c36' pt 6 ps 1 lt 1 lw 2 # --- green
  20 set style line 3 lc rgb '#003399' pt 1 ps 1 lt 1 lw 2 # --- blue
  21 plot filename every ::2::97 using 5:7 smooth unique with lines title 'Read Only', \
  22 filename every ::98::193 using 5:7 smooth unique with lines title 'Read Write', \
  23 filename every ::194::298 using 5:7 smooth unique with lines title 'Custom'